Add initial symbols queries

runtime/queries/c/symbols.scm

@@ -0,0 +1,9 @@
+(function_declarator
+  declarator: [(identifier) (field_identifier)] @definition.function)
+
+(preproc_function_def name: (identifier) @definition.function)
+
+(type_definition
+  declarator: (type_identifier) @definition.type)
+
+(preproc_def name: (identifier) @definition.constant)

runtime/queries/cpp/symbols.scm

@@ -0,0 +1,12 @@
+; inherits: c
+
+(function_declarator
+  declarator: (qualified_identifier name: (identifier) @definition.function))
+
+(struct_specifier
+  name: (type_identifier) @definition.struct
+  body: (field_declaration_list))
+
+(class_specifier
+  name: (type_identifier) @definition.class
+  body: (field_declaration_list))

runtime/queries/elixir/symbols.scm

@@ -0,0 +1,10 @@
+((call
+   target: (identifier) @_keyword
+   (arguments
+     [
+       (call target: (identifier) @definition.function)
+       ; function has a guard
+       (binary_operator
+         left: (call target: (identifier) @definition.function))
+     ]))
+ (#any-of? @_keyword "def" "defdelegate" "defguard" "defguardp" "defmacro" "defmacrop" "defn" "defnp" "defp"))

runtime/queries/erlang/symbols.scm

@@ -0,0 +1,45 @@
+; Modules
+(attribute
+  name: (atom) @_attr
+  (arguments (atom) @definition.module)
+ (#eq? @_attr "module"))
+
+; Constants
+((attribute
+    name: (atom) @_attr
+    (arguments
+      .
+      [
+        (atom) @definition.constant
+        (call function: [(variable) (atom)] @definition.macro)
+      ]))
+ (#eq? @_attr "define"))
+
+; Record definitions
+((attribute
+   name: (atom) @_attr
+   (arguments
+     .
+     (atom) @definition.struct))
+ (#eq? @_attr "record"))
+
+; Function specs
+((attribute
+    name: (atom) @_attr
+    (stab_clause name: (atom) @definition.interface))
+ (#eq? @_attr "spec"))
+
+; Types
+((attribute
+    name: (atom) @_attr
+    (arguments
+      (binary_operator
+        left: [
+          (atom) @definition.type
+          (call function: (atom) @definition.type)
+        ]
+        operator: "::")))
+ (#any-of? @_attr "type" "opaque"))
+
+; Functions
+(function_clause name: (atom) @definition.function)

runtime/queries/markdown/symbols.scm

@@ -0,0 +1,2 @@
+; TODO: have symbol types for markup?
+(atx_heading) @definition.class

runtime/queries/python/symbols.scm

@@ -0,0 +1,5 @@
+(function_definition
+  name: (identifier) @definition.function)
+
+(class_definition
+  name: (identifier) @definition.class)